| Toprak |
27 Ocak 2015 22:51 |
HostServ [Socket Sistem]
Kod:
alias sunucu return irc.sunucu.com 6667
alias opers return Aeg 123456
alias nickpass return 123456
alias hostserv {
if ($1 == bagla) { sockclose hostserv | sockopen hostserv $sunucu | echo -a HostServ Baglanmistir. }
if ($1 == kopar) { sockclose hostserv | echo -a HostServ Baglantisi Kopmustur. }
}
alias hostver {
sw hostserv chghost $1 $gettok($read(host.63,w,$+($1,$chr(42),*)),2,42)
}
alias hostadd {
if ($read(host.63,w,$+($2,$chr(42),*))) { sw hostserv notice $1 $2 Adina Eskiden Kayit Bulunmaktadir , ve Degistirilmistir. | write $+(-dl,$+($2,$chr(42),*)) host.63 }
sw hostserv notice $1 Host Eklenmistir.
sw hostserv notice $1 Nick: $2
sw hostserv notice $1 Host: $3
write host.63 $+($2,$chr(42),$3)
}
alias hostdel {
if (!$read(host.63,w,$+($2,$chr(42),*))) { sw hostserv notice $1 $2 Adina kayit bulunmamaktadir. | halt }
sw hostserv notice $1 $2 Adina Oto Host Sistemi Sistemden Silinmistir. Hostu: $gettok($read(host.63,w,$+($2,*)),2,42)
write $+(-dl,$readn) host.63
}
alias goster {
if (!$2) {
var %s 1
var %xx $lines(host.63)
if (%xx == 0) { sw hostserv notice $1 Listede kayit bulunmamaktadir. | halt }
sw hostserv notice $1 - HostServ List -
sw hostserv notice $1 -
while (%s <= $lines(host.63)) {
sw hostserv notice $1 Nick: $gettok($read(host.63,%s),1,42) Host: $gettok($read(host.63,%s),2,42)
inc %s
}
sw hostserv notice $1 -
sw hostserv notice $1 HostServ List The End -
halt
}
if ($2 == -r) { sw $sockname notice $1 HostServre Ait Butun Bilgiler Sifirlanmistir. | write -c host.63 | halt }
if (!$read(host.63,w,$+($1,$chr(42),*))) { sw hostserv notice $1 $2 Adina kayit bulunmamaktadir. | halt }
sw hostserv notice $1 Nick: $($chr(2),$gettok($read(host.63,w,$+($2,$chr(42),*)),1,42),$chr(2)) Host: $+($chr(2),$gettok($read(host.63,w,$+($2,$chr(42),*)),2,42),$chr(2))
}
alias sw {
if $sock($1).status == active {
sockwrite -nt $1-
}
}
on *:SOCKOPEN:hostserv: {
sw $sockname nick Services $+ $r(0,99)
sw $sockname USER 63 " " : $+ $+([,,HostServ,,]) (System v1 by Aeg)
}
on *:sockread:hostserv: {
if !$sock($sockname) { echo -a Baglanti Koptu! | halt }
var %q
sockread %q
tokenize 32 %q
if $1 == error && $2 == :closing {
hostserv bagla
}
if $1 == PING {
sw $sockname PONG $2
}
if $2 == 376 {
sw $sockname oper $opers
sw $sockname join 0,
sw $sockname nick HostServ
sw $sockname identify $nickpass
sw $sockname sethost services.bot
sw $sockname setident Server
sw $sockname stats o
.timerlist 0 2 sw $sockname list
sw $sockname mode hostserv +p
}
if ($2 == 322) {
if ($5 <= 1) { sw $sockname part $4 }
if ($5 >= 2) {
sw $sockname join $4
}
}
if ($2 == 352) && (r isin $9) {
.hostver $8
.timer $+ $8 off
}
if ($2 == 243) {
%operler = $addtok(%operler,$7,32)
}
if ($2 == privmsg) {
var %n = $gettok($gettok($1,1,33),1,58), %m = $4,%text = $right($4-,-1), %k = $3
if (%k == HostServ) {
var %komutlar = on list add del help
if (!$istok(%komutlar ,$remove($4,:),32)) { sw $sockname notice %n $remove($4,:) ait komut kulunmamaktadir. | halt }
if (!$istok(%operler ,%n,32)) { sw $sockname notice %n Bu komutu kullanmaya yetkili degilsiniz! | halt }
if (help isin %m) {
sw $sockname notice %n Merhaba %n , HostServ help Commands Lists.
sw $sockname notice %n -
sw $sockname notice %n /Msg Hotserv Help seklinde yazarak host systemi hakkinda bilgi alabilirsiniz.
sw $sockname notice %n -
sw $sockname notice %n /Msg hostserv add nick host komutu ;
sw $sockname notice %n *** nick yerine Host eklencek nick yazilcak , ***
sw $sockname notice %n *** host yerine Eklenecek host , Ornek: O.bir.UrfaLy ***
sw $sockname notice %n /msg hostserv del nick yazarak o nick'in ekli hostunu silebilirsiniz.
sw $sockname notice %n -
sw $sockname notice %n /msg hostserv list yazarak host listesine bakabilirsiniz.
sw $sockname notice %n -
sw $sockname notice %n -
sw $sockname notice %n /msg hostserv on yazarak oto hostunuzu alabilirsiniz.
sw $sockname notice %n -
sw $sockname notice %n $decode(1`EEA<&EM8VDZ`B!">2!!96<`)
}
if (add isin %m) {
if ($5 == $null) { sw $sockname notice %n Nick Yazmayi Unuttunuz , Ornek: /msg hostserv add Aeg O.bir.UrfaLy | halt }
if ($6 == $null) { sw $sockname notice %n Host Yazmayi Unuttunuz , Ornek: /msg hostserv add Aeg O.bir.UrfaLy | halt }
hostadd %n $5 $6
}
if (del isin %m) {
if ($5 == $null) { sw $sockname notice %n Nick Yazmayi Unuttunuz , Ornek: /msg hostserv del Aeg | halt }
hostdel %n $5
}
if (list isin %m) {
if ($5 !== $null) { goster %n $5 | halt }
goster %n
}
if (on isin %m) {
if (!$read(host.63,w,$+(%n,$chr(42),*))) { sw $sockname notice %n HostServe Kayitli Hostunuz Bulunmamaktadir! | halt }
if ($read(host.63,w,$+(%n,$chr(42),*))) {
hostver %n
sw $sockname notice %n Nickinize ait oto hostu almis bulunmaktasiniz.
}
}
}
}
if ($2 == notice) {
if (connecting isin $1-) {
if ($read(host.63,w,$+($12,$chr(42),*))) {
.timer $+ $12 60 1 sw $sockname who $12
}
}
}
if $2 == JOIN {
var %nick = $remove($gettok($1,1,33),:)
if ($read(host.63,w,$+(%nick,$chr(42),*))) {
.timer $+ %nick 60 1 sw $sockname who %nick
}
}
if $2 == NICK {
var %nickdegis = $remove($gettok($1,1,33),:) | var %newnick = $right($3,-1)
if ($read(host.63,w,$+(%newnick,$chr(42),*))) {
.timer $+ %newnick 60 1 sw $sockname who %newnick
}
}
}
on *:sockclose:hostserv: {
unset %operler
timerlist off
Merhaba IF uyeleri , konu adi ustunde hostserv socket sistem,
Bu sistem normal bir hostserv islevi yapmaktadir
Bu sistem orjinalin disinda sadece farki , sunucuda bulunan tum kanallara girmektedir.
Kullanim Sarti; Botun chghost Komutunu kullanabilmesi ve sajoin komutu kullanabilmesi gerekmektedir.
Bu Kısımlari Doldurduktan Sonra;
alias sunucu return irc.sunucu.com 6667
alias opers return Aeg 123456
alias nickpass return 123456
Botu Baglamak Icin ;
Botu IRC'e Baglamak icin => /hostserv bagla
Botun IRC Baglantisini Kopartmak Icın => /hostserv kopar
Detayli bilgileri gormek icin botu kurdugunuzda /msg hostserv help yaziniz. Ins. Isinize Yarar..
Hayirli IF'ler.. |
